de tutorial legt de moeren en bouten van Excel MONTH-en EOMONTH-functies uit. U vindt een reeks formulevoorbeelden die aantonen hoe u de maand vanaf de datum in Excel kunt extraheren, de eerste en laatste dag van de maand kunt krijgen, de maandnaam kunt converteren naar nummer en meer.

In het vorige artikel hebben we een verscheidenheid aan Excel-functies onderzocht om te werken met weekdagen en dagen van het jaar., Vandaag gaan we werken op een grotere tijdseenheid en de functies leren die Microsoft Excel maandenlang biedt.,onth aantal van de datum in Excel

Excel MAAND functie – syntaxis en het gebruik

Microsoft Excel bevat een speciale MAAND functie voor het uitpakken van een maand vanaf de datum, het resultaat is het nummer van de maand, variërend van 1 (januari) tot 12 (December).,

De functie maand kan worden gebruikt in alle versies van Excel 2016-2000 en de syntaxis is zo eenvoudig als het kan zijn:

waarbij serial_number is een geldige datum van de maand die u probeert te vinden.

voor het juiste werk van Excel-maandformules moet een datum worden ingevoerd met behulp van de functie Datum(Jaar, Maand, Dag). Bijvoorbeeld, de formule =MONTH(DATE(2015,3,1)) geeft 3 terug sinds Datum staat voor de 1ste dag van maart 2015.,

formules zoals =MONTH("1-Mar-2015") werken ook prima, hoewel er problemen kunnen optreden in complexere scenario ‘ s als datums als tekst worden ingevoerd.

in de praktijk is het handiger om in plaats van een datum binnen de functie maand te specificeren naar een cel met een datum te verwijzen of een datum te geven die door een andere functie wordt geretourneerd. Bijvoorbeeld:

=MONTH(A1) – geeft de maand van een datum in cel A1.

=MONTH(TODAY()) – geeft het nummer van de huidige maand.

op het eerste gezicht kan de Excel MONTH-functie er eenvoudig uitzien., Maar kijk door de onderstaande voorbeelden en je zult versteld staan om te weten hoeveel nuttige dingen het daadwerkelijk kan doen.

hoe maandnummer te krijgen vanaf datum in Excel

Er zijn verschillende manieren om Maand vanaf datum in Excel te krijgen. Welke te kiezen hangt af van precies welk resultaat u probeert te bereiken.

1. maand functie in Excel-krijg maandnummer vanaf datum.

   Dit is de meest voor de hand liggende en gemakkelijkste manier om datum naar maand te converteren in Excel. Bijvoorbeeld:

   • =MONTH(A2) – geeft de maand van een datum in cel A2 terug.,
   • =MONTH(DATE(2015,4,15)) – geeft 4 terug overeenkomend met April.
   • =MONTH("15-Apr-2015") – geeft uiteraard ook Nummer 4 terug.
2. tekstfunctie in Excel-extraheer maand als een tekstreeks.

   een alternatieve manier om een maandnummer te krijgen van een Excel-datum is met behulp van de tekstfunctie:

   • =TEXT(A2, "m") – geeft een maandnummer zonder voorloopnul terug, als 1 – 12.
   • =TEXT(A2,"mm") – geeft een maandnummer met een voorloopnul terug als 01 – 12.,

   wees voorzichtig bij het gebruik van TEKSTFORMULES, omdat ze altijd maandnummers als tekenreeksen retourneren. Dus als u van plan bent om nog een aantal berekeningen uit te voeren of de geretourneerde getallen in andere formules te gebruiken, kunt u beter vasthouden aan de Excel MONTH functie.

de volgende Schermafbeelding toont de resultaten van alle bovenstaande formules. Let op de juiste uitlijning van getallen die worden geretourneerd door de functie maand (cellen C2 en C3) in tegenstelling tot links uitgelijnde tekstwaarden die worden geretourneerd door de tekstfuncties (cellen C4 en C5).,

hoe de maandnaam uit de datum te extraheren in Excel

in het geval u een maandnaam wilt krijgen in plaats van een nummer, gebruikt u de tekstfunctie opnieuw, maar met een andere datum code:

• =TEXT(A2, "mmm") – geeft een verkorte maandnaam terug, als Jan – Dec.
• =TEXT(A2,"mmmm") – geeft een volledige maandnaam terug, als Januari – December.,

Als u in uw Excel-werkblad geen datum naar maand wilt converteren, wilt u alleen een maandnaam weergeven in plaats van de volledige datum, dan wilt u geen formules.

selecteer een cel (en) met datums, druk op Ctrl+1 om het dialoogvenster Cellen opmaken te openen. Selecteer op het tabblad Getal aangepast en typ ” mmm ” of “mmmm” in het vak Type om respectievelijk verkorte of volledige maandnamen weer te geven. In dit geval blijven uw vermeldingen volledig functionele Excel-datums die u kunt gebruiken in berekeningen en andere formules., Zie voor meer informatie over het wijzigen van de datumnotatie een aangepast datumnotatie maken in Excel.

hoe maandnummer naar maandnaam converteren in Excel

stel dat u een lijst met getallen (1 tot en met 12) in uw Excel-werkblad hebt die u naar maandnamen wilt converteren. Om dit te doen, kunt u een van de volgende formules gebruiken:

hoe deze formules werken

hoe maandnaam naar nummer converteren in Excel

Er zijn twee Excel – functies die u kunnen helpen maandnamen naar getallen te converteren-DATEVALUE en MONTH., Excel ‘ s DateValue functie converteert een datum opgeslagen als tekst naar een serienummer dat Microsoft Excel herkent als een datum. En dan haalt de functie maand een maandnummer uit die datum.

de volledige formule is als volgt:

=MONTH(DATEVALUE(A2 & "1"))

waarbij A2 in een cel met de maandnaam die u in een getal wilt veranderen (&”1″ wordt toegevoegd voor de DateValue-functie om te begrijpen dat het een datum is).,

hoe de laatste dag van de maand in Excel te krijgen (eomonth-functie)

De eomonth-functie in Excel wordt gebruikt om de laatste dag van de maand te retourneren op basis van de opgegeven startdatum. Het heeft de volgende argumenten, die beide vereist zijn:

• Start_date – de begindatum of een verwijzing naar een cel met de begindatum.
• maanden-het aantal maanden vóór of na de begindatum. Gebruik een positieve waarde voor toekomstige datums en een negatieve waarde voor voorbije datums.,

Hier zijn enkele voorbeelden van EOMONTH-formules:

=EOMONTH(A2, 1) – geeft de laatste dag van de maand terug, een maand na de datum in cel A2.

=EOMONTH(A2, -1) – geeft de laatste dag van de maand terug, een maand voor de datum in cel A2.

in plaats van een celverwijzing kunt u een datum hardcoderen in uw eomonth-formule. Beide onderstaande formules keren bijvoorbeeld de laatste dag in April terug.,

=EOMONTH("15-Apr-2015", 0)

=EOMONTH(DATE(2015,4,15), 0)

om de laatste dag van de huidige maand te retourneren, gebruikt u de functie TODAY() in het eerste argument van uw eomonth-formule zodat de datum van vandaag als startdatum wordt genomen. En je plaatst 0 in het months argument omdat je de maand hoe dan ook niet wilt veranderen.

=EOMONTH(TODAY(), 0)

En hier zijn de resultaten van de Excel LAATSTE formules hierboven besproken:

Als je wilt berekenen hoeveel dagen er nog resteren tot het einde van de huidige maand, je gewoon aftrekken van de datum geretourneerd door VANDAAG() vanaf de datum die wordt geretourneerd door de LAATSTE en zijn van toepassing de Algemene notatie op een cel:

=EOMONTH(TODAY(), 0)-TODAY()

Hoe vindt u de eerste dag van de maand in Excel

Zoals je al weet, Microsoft Excel biedt slechts een functie voor het retourneren van de laatste dag van de maand (de LAATSTE)., Als het gaat om de eerste dag van de maand, Er is meer dan een manier om het te krijgen.

Voorbeeld 1. Ontvang de 1e dag van de maand met het maandnummer

als u het maandnummer hebt, gebruik dan een eenvoudige datumformule als volgt:

bijvoorbeeld =DATE(2015, 4, 1) geeft 1-Apr-15 terug.

als uw getallen zich in een bepaalde kolom bevinden, bijvoorbeeld in kolom A, kunt u direct een celverwijzing toevoegen in de formule:

=DATE(2015, B2, 1)

Voorbeeld 2., Haal de 1e dag van de maand op vanaf een datum

Als u de eerste dag van de maand wilt berekenen op basis van een datum, kunt u de Excel-datumfunctie opnieuw gebruiken, maar deze keer hebt u ook de functie maand nodig om het maandnummer te extraheren:

bijvoorbeeld, de volgende formule retourneert de eerste dag van de maand op basis van de datum in cel A2:

=DATE(2015,MONTH(A2),1)

voorbeeld 3., Zoek de eerste dag van de maand op basis van de huidige datum

wanneer uw berekeningen zijn gebaseerd op de datum van vandaag, gebruik dan een liaison van de Excel EOMONTH en TODAY functies:

=EOMONTH(TODAY(),0) +1 – geeft de 1e dag van de volgende maand.

zoals u zich herinnert, hebben we al een soortgelijke eomonth-formule gebruikt om de laatste dag van de huidige maand te krijgen. En nu voeg je gewoon 1 toe aan die formule om de eerste dag van de volgende maand te krijgen.,

op dezelfde manier kunt u de eerste dag van de vorige en huidige maand krijgen:

=EOMONTH(TODAY(),-2) +1 – geeft de eerste dag van de vorige maand terug.

=EOMONTH(TODAY(),-1) +1 – geeft de eerste dag van de huidige maand terug.

u kunt ook de Excel-datumfunctie gebruiken om deze taak af te handelen, hoewel de formules iets langer zouden zijn. Bijvoorbeeld, raad eens wat de volgende formule doet?

=DATE(YEAR(TODAY()), MONTH(TODAY()), 1)

Yep, het geeft de eerste dag van de huidige maand.

en hoe forceer je het om de eerste dag van de volgende of vorige maand terug te keren?, Hands down 🙂 gewoon 1 optellen of aftrekken van de huidige maand:

om de eerste dag van de volgende maand te retourneren:

=DATE(YEAR(TODAY()), MONTH(TODAY())+1, 1)

om de eerste dag van de vorige maand te retourneren:

=DATE(YEAR(TODAY()), MONTH(TODAY())-1, 1)

het aantal dagen in een maand berekenen

in Microsoft Excel bestaan verschillende functies om met datums en tijden te werken. Het ontbreekt echter aan een functie voor het berekenen van het aantal dagen in een bepaalde maand. Dus moeten we dat goedmaken met onze eigen formules.

Voorbeeld 1., Om het aantal dagen te krijgen op basis van het maandnummer

Als u het maandnummer kent, retourneert de volgende dag / datum-formule het aantal dagen in die maand:

in de bovenstaande formule retourneert de functie DATE de eerste dag van de volgende maand, waarvan u 1 aftrekt om de laatste dag van de gewenste maand te krijgen. En dan converteert de functie dag de datum naar een dagnummer.

bijvoorbeeld, de volgende formule geeft het aantal dagen in April (de 4e maand in het jaar).,

=DAY(DATE(2015, 4 +1, 1) -1)

Voorbeeld 2. Om het aantal dagen in een maand te krijgen op basis van datum

Als u geen maandnummer kent maar een datum binnen die maand hebt, kunt u de functie jaar en maand gebruiken om het jaar-en maandnummer uit de datum te extraheren. Sluit ze gewoon in in de dag / datum-formule die in het bovenstaande voorbeeld wordt besproken, en het zal u vertellen hoeveel dagen een bepaalde maand bevat:

=DAY(DATE(YEAR(A2), MONTH(A2) +1, 1) -1)

waarin A2 cel met een datum is.

U kunt ook een veel eenvoudiger dag / EOMONTH formule gebruiken., Zoals u zich herinnert, retourneert de Excel EOMONTH-functie de laatste dag van de maand, dus u hebt geen extra berekeningen nodig:

=DAY(EOMONTH(A1, 0))

De volgende Schermafbeelding toont de resultaten die door alle formules worden geretourneerd, en zoals u ziet zijn ze identiek:

gegevens per maand optellen in Excel

in een grote tabel met veel gegevens moet u vaak een som van waarden voor een bepaalde maand krijgen. En dit zou een probleem kunnen zijn als de gegevens niet in chronologische volgorde werden ingevoerd.,

De eenvoudigste oplossing is om een hulpkolom toe te voegen met een eenvoudige Excel-MAANDFORMULE die datums converteert naar maandnummers. Zeg, als uw datums in kolom A staan, gebruikt u = MONTH (A2).

en schrijf nu een lijst met getallen (van 1 tot 12, of alleen die maandnummers die voor u van belang zijn) in een lege kolom, en somwaarden voor elke maand met behulp van een SUMIF-formule vergelijkbaar met deze:

=SUMIF(C2:C15, E2, B2:B15)

waarbij E2 het maandnummer is.,

de volgende Schermafbeelding toont het resultaat van de berekeningen:

Als u liever geen hulpkolom aan uw Excel-blad toevoegt, geen probleem, kunt u zonder. Een beetje lastiger SUMPRODUCT functie zal werken een traktatie:

=SUMPRODUCT((MONTH($A$2:$A$15)=$E2) * ($B$2:$B$15))

waar kolom A bevat datums, kolom B bevat de waarden op te tellen en E2 is het maandnummer.

conditioneel datums opmaken op basis van maand

Nu u weet hoe u de Excel MONTH-en EOMONTH-functies kunt gebruiken om verschillende berekeningen in uw werkbladen uit te voeren, kunt u een stap verder gaan en de visuele presentatie verbeteren. Hiervoor gaan we de mogelijkheden van Excel voorwaardelijke opmaak gebruiken voor datums.,

naast de voorbeelden in het hierboven genoemde artikel, zal ik u nu laten zien hoe u snel alle cellen of hele rijen met betrekking tot een bepaalde maand kunt markeren.

Voorbeeld 1. Markeer datums binnen de huidige maand

in de tabel uit het vorige voorbeeld, stel dat u alle rijen met de huidige maanddatums wilt markeren.

ten eerste extraheert u de maandnummers uit datums in kolom A met behulp van de eenvoudigste =MONTH($A2) formule. En dan vergelijk je die nummers met de huidige maand die wordt geretourneerd door = MONTH (TODAY ())., Als gevolg hiervan hebt u de volgende formule die TRUE retourneert als de maanden’ nummers overeenkomen, FALSE anders:

=MONTH($A2)=MONTH(TODAY())

Maak een Excel conditionele opmaakregel op basis van deze formule, en uw resultaat kan lijken op de screenshot hieronder (het artikel is geschreven in April, dus alle datums van April zijn gemarkeerd).

Voorbeeld 2. Datums markeren op maand en dag

en hier is een andere uitdaging. Stel dat u de belangrijkste feestdagen in uw werkblad wilt markeren, ongeacht het jaar. Laten we zeggen Kerst en Nieuwjaar dagen., Hoe zou u deze taak aanpakken?

gebruik gewoon de Excel DAY – functie om de dag van de maand (1-31) en de MONTH-functie te extraheren om het maandnummer te krijgen, en controleer dan of de dag gelijk is aan 25 of 31, en of de maand gelijk is aan 12:

=AND(OR(DAY($A2)=25, DAY($A2)=31), MONTH(A2)=12)

Dit is hoe de MONTH-functie in Excel werkt. Het lijkt veel veelzijdiger dan het lijkt, hè?

in een paar van de volgende berichten gaan we weken en jaren berekenen en hopelijk leer je nog een paar nuttige trucs., Als u geïnteresseerd bent in kleinere tijdseenheden, bekijk dan de vorige delen van onze Excel-datumreeks (u vindt de links hieronder). Ik dank u voor het lezen en hoop u volgende week te zien!

• Hoe verander ik de datumnotatie in Excel en maak aangepaste datumnotaties
• Hoe maak ik een agenda in Excel (drop-down en afdrukbare)
• Hoe voeg ik datums in Excel in
• hoe converteer ik tekst naar datum in Excel
• Excel-datums converteren naar tekstformaat
• werken met weekdagen en dagen van de maand in Excel